From df4d11bb95bc7ea9554b55d2211c4704a2594f08 Mon Sep 17 00:00:00 2001
From: Gabriel Schneider <gbrls@0x4200.cafe>
Date: Mon, 28 Sep 2026 17:04:53 -0300
Subject: ]f, mif and the other textobject keys use helix's own queries

helix's textobjects.scm for pardes's grammars are vendored in vendor/queries
under MPL-2.0, each with a header naming its source and what it inherits,
inlined; a README says what is there and what is not. syntax.objectAt and
objectNext run them over the file's kept parse, with their #eq? and #match?
predicates, for ]f [f ]t [t ]a [a ]c [c ]T [T ]e [e ]x [x and mi/ma with
f t a c T e x. erlang's and zig's queries do not compile against the grammar
versions pardes builds and are left out; fortran, markdown and powershell
have none in helix. A test replays sixteen Python and JSON cases whose
results were taken from the installed hx, and another holds that every
vendored query compiles.

Co-Authored-By: Claude Opus 5.5 <noreply@anthropic.com>
---
 vendor/queries/ruby/textobjects.scm | 61 +++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 vendor/queries/ruby/textobjects.scm

(limited to 'vendor/queries/ruby/textobjects.scm')

diff --git a/vendor/queries/ruby/textobjects.scm b/vendor/queries/ruby/textobjects.scm
new file mode 100644
index 00000000..368d80b9
--- /dev/null
+++ b/vendor/queries/ruby/textobjects.scm
@@ -0,0 +1,61 @@
+; Vendored from helix (https://github.com/helix-editor/helix) at 278b24389:
+; runtime/queries/ruby/textobjects.scm.
+; Licensed under the Mozilla Public License 2.0 (vendor/queries/helix.LICENSE,
+; https://mozilla.org/MPL/2.0/).
+
+; Class and Modules
+(class
+  body: (_)? @class.inside) @class.around
+
+(singleton_class
+  value: (_)
+  (_)+ @class.inside) @class.around
+
+(call
+  receiver: (constant) @class_const
+  method: (identifier) @class_method
+  (#match? @class_const "Class")
+  (#match? @class_method "new")
+  (do_block (_)+ @class.inside)) @class.around
+  
+(module
+  body: (_)? @class.inside) @class.around
+
+; Functions and Blocks
+(singleton_method
+  body: (_)? @function.inside) @function.around
+
+(method
+  body: (_)? @function.inside) @function.around
+
+(do_block
+  body: (_)? @function.inside) @function.around
+
+(block
+  body: (_)? @function.inside) @function.around
+
+; Parameters      
+(method_parameters
+  (_) @parameter.inside) @parameter.around
+        
+(block_parameters 
+  (_) @parameter.inside) @parameter.around
+        
+(lambda_parameters 
+  (_) @parameter.inside) @parameter.around
+
+; Comments
+(comment) @comment.inside 
+(comment)+ @comment.around
+
+(pair
+  (_) @entry.inside) @entry.around
+
+(array
+  (_) @entry.around)
+
+(string_array
+  (_) @entry.around)
+
+(symbol_array
+  (_) @entry.around)
-- 
cgit v1.3