summaryrefslogtreecommitdiff
path: root/src/cli/record.zig
blob: ab617d453a7dd3b38760ea89a0b3ae6f4bb773ec (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
//! ztrace record: a program under ptrace, every stop a moment.
const std = @import("std");
const zt = @import("ztrace");
const util = @import("util.zig");
const fail = util.fail;

pub const usage =
    \\usage: ztrace record [-o FILE] [--steps N] [--syscalls] [--stack BYTES] -- PROGRAM [ARGS]
    \\
    \\Runs PROGRAM under ptrace into a recording (default out.ztrace): every
    \\instruction, or with --syscalls every syscall. --steps stops after N
    \\moments. --stack records that many bytes above the stack pointer at each
    \\stop (default 128).
    \\
;

pub fn run(init: std.process.Init, args: []const [:0]const u8) !void {
    const arena = init.arena.allocator();
    var out: []const u8 = "out.ztrace";
    var max_moments: u64 = std.math.maxInt(u64);
    var by_syscall = false;
    var stack_bytes: usize = 128;
    var i: usize = 0;
    while (i < args.len) : (i += 1) {
        const arg = args[i];
        if (std.mem.eql(u8, arg, "--")) {
            i += 1;
            break;
        } else if (std.mem.eql(u8, arg, "-o") and i + 1 < args.len) {
            i += 1;
            out = args[i];
        } else if (std.mem.eql(u8, arg, "--steps") and i + 1 < args.len) {
            i += 1;
            max_moments = std.fmt.parseInt(u64, args[i], 0) catch fail("--steps needs a number\n", .{});
        } else if (std.mem.eql(u8, arg, "--stack") and i + 1 < args.len) {
            i += 1;
            stack_bytes = std.fmt.parseInt(usize, args[i], 0) catch fail("--stack needs a number\n", .{});
        } else if (std.mem.eql(u8, arg, "--syscalls")) {
            by_syscall = true;
        } else fail(usage, .{});
    }
    if (i >= args.len) fail(usage, .{});

    const path = try util.resolve(init, args[i]);
    const argv = try util.targetArgv(arena, args[i..]);
    var proc = try zt.ptrace.Process.spawn(path, argv, init.minimal.environ.block.slice.ptr);
    errdefer proc.kill();

    var rec = try zt.Recorder.create(init.gpa, init.io, out);
    const tid: u32 = @intCast(proc.pid);
    const stack = try arena.alloc(u8, stack_bytes);
    const stack_seen = try arena.alloc(u8, stack_bytes);
    var stack_at: u64 = 0;

    var timer = zt.event.now();
    var exit_code: u64 = 0;
    while (rec.moments < max_moments) {
        const stop = if (by_syscall) try proc.syscall() else try proc.stepi();
        switch (stop) {
            .exited => |code| {
                exit_code = code;
                try rec.emit(.{ .ts = zt.event.now(), .tid = tid, .kind = .exit, .a = .{ code, 0, 0, 0, 0, 0 } }, "");
                break;
            },
            .killed => |sig| {
                exit_code = 128 + @as(u64, @intFromEnum(sig));
                try rec.emit(.{ .ts = zt.event.now(), .tid = tid, .kind = .exit, .a = .{ exit_code, 0, 0, 0, 0, 0 } }, "");
                break;
            },
            .signal => |sig| try rec.emit(.{ .ts = zt.event.now(), .tid = tid, .kind = .signal, .aux = @intCast(@intFromEnum(sig)) }, ""),
            .trap, .syscall => {
                const regs = try proc.regs();
                // The stack above rsp: only the bytes that changed since the last stop.
                const n = proc.read(regs.rsp, stack);
                if (regs.rsp != stack_at) @memset(stack_seen, 0);
                var from: usize = 0;
                while (from < n) {
                    if (regs.rsp == stack_at and stack[from] == stack_seen[from]) {
                        from += 1;
                        continue;
                    }
                    var to = from + 1;
                    while (to < n and (regs.rsp != stack_at or stack[to] != stack_seen[to])) to += 1;
                    try rec.emit(.{ .ts = zt.event.now(), .tid = tid, .kind = .mem_write, .a = .{ regs.rsp + from, to - from, regs.rip, 0, 0, 0 } }, stack[from..to]);
                    from = to;
                }
                @memcpy(stack_seen[0..n], stack[0..n]);
                stack_at = regs.rsp;

                const ev: zt.Event = if (stop == .trap)
                    .{ .ts = zt.event.now(), .tid = tid, .kind = .step, .a = .{ regs.rip, 0, 0, 0, 0, 0 } }
                else if (proc.in_syscall)
                    .{ .ts = zt.event.now(), .tid = tid, .kind = .syscall_enter, .aux = @truncate(regs.orig_rax), .a = .{ regs.rdi, regs.rsi, regs.rdx, regs.r10, regs.r8, regs.r9 } }
                else
                    .{ .ts = zt.event.now(), .tid = tid, .kind = .syscall_exit, .aux = @truncate(regs.orig_rax), .a = .{ regs.rax, 0, 0, 0, 0, 0 } };
                try rec.emit(ev, std.mem.asBytes(&regs));
            },
        }
    } else proc.kill();
    timer = zt.event.now() - timer;

    const moments = rec.moments + @intFromBool(rec.delta.items.len > 0);
    const events = rec.count;
    try rec.close();
    const size = (try std.Io.Dir.cwd().statFile(init.io, out, .{})).size;
    std.debug.print("{s}: {d} moments, {d} events, {d} bytes ({d} bytes/moment), {d:.1} ms, {d:.0} moments/s, exit {d}\n", .{
        out,                                                                           moments,
        events,                                                                        size,
        size / @max(moments, 1),                                                       @as(f64, @floatFromInt(timer)) / 1e6,
        @as(f64, @floatFromInt(moments)) / (@as(f64, @floatFromInt(timer)) / 1e9), exit_code,
    });
}