]f, mif and the other textobject keys use helix's own queries

helix's textobjects.scm for pardes's grammars are vendored in vendor/queries
under MPL-2.0, each with a header naming its source and what it inherits,
inlined; a README says what is there and what is not. syntax.objectAt and
objectNext run them over the file's kept parse, with their #eq? and #match?
predicates, for ]f [f ]t [t ]a [a ]c [c ]T [T ]e [e ]x [x and mi/ma with
f t a c T e x. erlang's and zig's queries do not compile against the grammar
versions pardes builds and are left out; fortran, markdown and powershell
have none in helix. A test replays sixteen Python and JSON cases whose
results were taken from the installed hx, and another holds that every
vendored query compiles.

Co-Authored-By: Claude Opus 5.5 <[email protected]>

1 files changed, 63 insertions, 0 deletions

diff --git a/vendor/queries/php/textobjects.scm b/vendor/queries/php/textobjects.scm
new file mode 100644
index 00000000..8bf7fab9
--- /dev/null
+++ b/vendor/queries/php/textobjects.scm
@@ -0,0 +1,63 @@
+; Vendored from helix (https://github.com/helix-editor/helix) at 278b24389:
+; runtime/queries/php/textobjects.scm.
+; Licensed under the Mozilla Public License 2.0 (vendor/queries/helix.LICENSE,
+; https://mozilla.org/MPL/2.0/).
+
+(class_declaration
+  body: (_) @class.inside) @class.around
+
+(interface_declaration
+  body: (_) @class.inside) @class.around
+
+(trait_declaration
+  body: (_) @class.inside) @class.around
+
+(enum_declaration
+  body: (_) @class.inside) @class.around
+
+(function_definition
+  body: (_) @function.inside) @function.around
+
+(method_declaration
+  body: (_) @function.inside) @function.around
+
+(arrow_function 
+  body: (_) @function.inside) @function.around
+  
+(anonymous_function
+  body: (_) @function.inside) @function.around
+
+(anonymous_class
+  body: (_) @class.inside) @class.around
+
+(property_hook
+  body: (_) @function.inside) @function.around
+
+(anonymous_function_use_clause
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(formal_parameters
+  ([
+    (simple_parameter)
+    (variadic_parameter)
+    (property_promotion_parameter)
+  ] @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(arguments
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(comment) @comment.inside
+
+(comment)+ @comment.around
+
+(array_creation_expression
+  (array_element_initializer
+    (_) @entry.inside
+  ) @entry.around @entry.movement)
+
+(list_literal
+  (_) @entry.inside @entry.around @entry.movement)
+
+[
+  (enum_case)
+] @entry.around @entry.movement