1 files changed, 0 insertions, 83 deletions
diff --git a/shaders/prebuilt/decor.frag.glsl b/shaders/prebuilt/decor.frag.glsl
deleted file mode 100644
index bb1ef0d6..00000000
--- a/shaders/prebuilt/decor.frag.glsl
+++ /dev/null
@@ -1,83 +0,0 @@
-#version 450
-
-// Decor, drawn by ui.vert.glsl like a cell, its track's transition included,
-// and blended as the overlay pipeline blends (backgroundLayerBlend). Ink (a
-// cursor) is drawn with the opacity uniform at 1.
-//
-// Flat: a hard-edged fill (a rule, a rail, a grip mark, a bar cursor). Its
-// colour rides in the cell's ground (a_bg), its coverage in a_fg.r, so the
-// result is the overlay pipeline's exactly.
-//
-// Checker (flag 0x08000000): two colours in squares, or in stripes, see main.
-//
-// Soft (flag 0x10000000): a rectangle's shadow, rim or glow blurred by a Gaussian,
-// in closed form (the product of two erf edges), on one quad grown by 3
-// sigma: no blur pass. Everything is in the quad's own 0..1 space, so a
-// track's transform carries it: sigma per axis in the uv, the caster's
-// offset from its shadow in fg.gb, the strength in fg.r. The caster's own
-// rectangle is left alone (it is drawn already), and the alpha is pre-warped
-// so black darkens in linear light, then dithered so it never bands.
-
-layout(std140, set = 3, binding = 0) uniform UiUniforms {
-    float background_opacity;
-} u_ui;
-
-layout(location = 0) in vec2 v_uv;
-layout(location = 1) in vec3 v_fg;
-layout(location = 2) in vec3 v_bg;
-layout(location = 3) in vec2 v_cell_uv;
-layout(location = 4) flat in uvec4 v_effect;
-layout(location = 5) flat in vec4 v_clip;
-
-layout(location = 0) out vec4 o_col;
-
-// erf to about 4e-4 (Winitzki's approximation): smooth, cheap, odd.
-float erfApprox(float x) {
-    float x2 = x * x;
-    const float a = 0.147;
-    float e = sqrt(1.0 - exp(-x2 * (1.2732395 + a * x2) / (1.0 + a * x2)));
-    return x < 0.0 ? -e : e;
-}
-
-// How much of [lo, hi] a Gaussian of sigma s centred at x covers.
-float edge(float x, float lo, float hi, float s) {
-    float k = 0.70710678 / s;
-    return 0.5 * (erfApprox((x - lo) * k) - erfApprox((x - hi) * k));
-}
-
-float ign(vec2 p) {
-    return fract(52.9829189 * fract(dot(p, vec2(0.06711056, 0.00583715))));
-}
-
-void main() {
-    if (v_clip.z >= v_clip.x && (gl_FragCoord.x < v_clip.x || gl_FragCoord.x >= v_clip.z ||
-        gl_FragCoord.y < v_clip.y || gl_FragCoord.y >= v_clip.w)) discard;
-    float opacity = clamp(u_ui.background_opacity, 0.0, 1.0);
-    // Checker (flag 0x08000000): squares of v_uv.x pixels from the quad's
-    // own corner, so it moves with its rail, in the ground's colour and the
-    // ink's (lapis's scroll track).
-    vec2 in_quad = v_cell_uv / max(vec2(dFdx(v_cell_uv.x), dFdy(v_cell_uv.y)), vec2(1e-6));
-    if ((v_effect.x & 0x08000000u) != 0u) {
-        ivec2 q = ivec2(floor(in_quad / max(v_uv.x, 1.0)));
-        // v_uv.y set: stripes across the quad (lapis's title bar), not squares.
-        int k = v_uv.y > 0.5 ? q.y : q.x + q.y;
-        o_col = vec4(((k & 1) == 0 ? v_bg : v_fg) * opacity, 1.0);
-        return;
-    }
-    if ((v_effect.x & 0x10000000u) == 0u) {
-        o_col = vec4(v_bg * opacity, v_fg.r);
-        return;
-    }
-    vec2 s = v_uv;
-    vec2 m = 3.0 * s;
-    vec2 p = v_cell_uv;
-    vec2 caster0 = m - v_fg.gb;
-    vec2 caster1 = 1.0 - m - v_fg.gb;
-    if (all(greaterThanEqual(p, caster0)) && all(lessThan(p, caster1))) discard;
-    float a = v_fg.r * edge(p.x, m.x, 1.0 - m.x, s.x) * edge(p.y, m.y, 1.0 - m.y, s.y);
-    // Black darkens in linear light; a light colour (a rim, a glow) is laid
-    // on as it is, within §8.2's 25%.
-    if (all(equal(v_bg, vec3(0.0)))) a = 1.0 - pow(max(1.0 - a, 0.0), 1.0 / 2.2);
-    a = clamp(a + (ign(gl_FragCoord.xy) - 0.5) / 255.0, 0.0, 1.0);
-    o_col = vec4(v_bg * opacity, a);
-}