1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
#version 450
layout(set = 2, binding = 0) uniform sampler2D u_image;
layout(std140, set = 3, binding = 0) uniform UiUniforms {
float background_opacity;
} u_ui;
layout(location = 0) in vec2 v_uv;
layout(location = 1) in vec2 v_panel_uv;
layout(location = 2) flat in uvec4 v_effect;
layout(location = 0) out vec4 o_col;
float cellNoise(uint serial, uint col, uint row) {
uint x = serial ^ (col * 0x9e3779b9u) ^ (row * 0x85ebca6bu);
x ^= x >> 16;
x *= 0x7feb352du;
x ^= x >> 15;
x *= 0x846ca68bu;
x ^= x >> 16;
return float(x & 0xffffu) / 65535.0;
}
void main() {
vec4 source = texture(u_image, v_uv);
// Keep source coverage for destination subtraction; the pipeline scales
// source alpha by the same opacity through its alpha blend constant.
source.rgb *= clamp(u_ui.background_opacity, 0.0, 1.0);
uint effect = v_effect.x & 0x7fffffffu;
bool oldLayer = (v_effect.x & 0x80000000u) != 0u;
float progress = clamp(uintBitsToFloat(v_effect.y), 0.0, 1.0);
uvec2 dimensions = max(
uvec2(v_effect.w & 0xffffu, v_effect.w >> 16),
uvec2(1u));
uvec2 cellCoord = min(
uvec2(floor(max(v_panel_uv, vec2(0.0)) * vec2(dimensions))),
dimensions - 1u);
float noise = cellNoise(v_effect.z, cellCoord.x, cellCoord.y);
if (effect == 3u) {
bool reveal = progress >= 1.0 || (progress > 0.0 && noise < progress);
if (oldLayer == reveal) discard;
o_col = source;
return;
}
o_col = source;
}
|
