1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
// Glitch: now and then the signal slips. At the default level, every couple
// of seconds a short
// burst tears a few horizontal bands sideways and pulls their red and blue
// apart; the bands are sized in pixels and the burst eases in and out over
// a fraction of a second, so it reads as one event rather than a flicker,
// and it looks the same at 60 or 144 Hz because every step is keyed to
// iTime, not to frames. Between bursts the page is left exactly as it is.
// A torn band's brightness dips in linear light. It is a Shadertoy file:
// pardes puts its prefix before it.
// Each at levels 1, 2 and 3 (`Glitch 1`..`Glitch 3`); 2 is the default. A
// higher level slips more often and harder.
float period() { return pardesByLevel(4.5, 2.4, 0.55); } // seconds between bursts, on average
float burst() { return pardesByLevel(0.2, 0.28, 0.5); } // seconds a burst lasts
float stepHz() { return pardesByLevel(20.0, 24.0, 30.0); } // how often a burst re-tears
float shiftPx() { return pardesByLevel(8.0, 14.0, 34.0); }
float splitPx() { return pardesByLevel(1.5, 2.5, 6.0); }
float dip() { return pardesByLevel(0.08, 0.12, 0.22); }
float tearFrom() { return pardesByLevel(0.8, 0.72, 0.35); } // how few bands tear
float hash(vec2 p) {
vec3 q = fract(vec3(p.xyx) * 0.1031);
q += dot(q, q.yzx + 33.33);
return fract((q.x + q.y) * q.z);
}
vec3 toLinear(vec3 c) {
return mix(pow((c + 0.055) / 1.055, vec3(2.4)), c / 12.92, lessThanEqual(c, vec3(0.04045)));
}
vec3 toSrgb(vec3 c) {
c = max(c, vec3(0.0));
return mix(1.055 * pow(c, vec3(1.0 / 2.4)) - 0.055, c * 12.92, lessThanEqual(c, vec3(0.0031308)));
}
void mainImage(out vec4 fragColor, in vec2 fragCoord) {
vec2 size = iResolution.xy;
vec2 uv = fragCoord / size;
// Which burst window this is, when in it the burst starts, and how far
// into the burst we are: 0 outside one.
float window = floor(iTime / period());
float start = window * period() + hash(vec2(window, 7.0)) * (period() - burst());
float t = (iTime - start) / burst();
float live = step(0.0, t) * step(t, 1.0);
float envelope = live * sin(3.14159265 * clamp(t, 0.0, 1.0));
if (envelope <= 0.0) {
fragColor = texture(iChannel0, uv);
return;
}
// Bands of 6 to 40 px, re-cut at stepHz() during the burst; about one
// band in four tears.
float tick = floor(iTime * stepHz());
float band_px = mix(6.0, 40.0, hash(vec2(tick, 3.0)));
float band = floor(fragCoord.y / band_px);
float roll = hash(vec2(band, tick));
float tear = smoothstep(tearFrom(), tearFrom() + 0.18, roll) * envelope;
float shift = (hash(vec2(tick, band + 11.0)) - 0.5) * 2.0 * shiftPx() * tear;
vec2 at = vec2(fragCoord.x + shift, fragCoord.y);
vec2 split = vec2(splitPx() * tear, 0.0);
vec4 center = texture(iChannel0, at / size);
vec3 col = vec3(texture(iChannel0, (at + split) / size).r, center.g, texture(iChannel0, (at - split) / size).b);
col = toSrgb(toLinear(col) * (1.0 - dip() * tear));
fragColor = vec4(col, center.a);
}
|
