summaryrefslogtreecommitdiff
path: root/test/behaviour/flags.zig
blob: 0c8b666053ff98cc350f7632e5d7688921d1294d (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
//! docs/typ/reference.typ, Flags and undo <flags>.
const std = @import("std");
const Session = @import("session").Session;

test "flags: dirty, mark and scroll read and write the state acme kept behind ctl verbs, 1 or 0" {
    var s = try Session.initFile(std.testing.allocator, "one\ntwo\n");
    defer s.deinit();
    const n = try s.focused();
    const dirty = s.at("/pane/{d}/dirty", .{n});
    const mark = s.at("/pane/{d}/mark", .{n});
    const scroll = s.at("/pane/{d}/scroll", .{n});
    for ([_][]const u8{ dirty, mark, scroll }) |flag| {
        try std.testing.expectEqual(@as(u64, 2), (try s.stat(flag)).size);
        for ([_][]const u8{ "", "yes", "2", "0 1", "true" }) |bad| {
            try std.testing.expectEqual(@as(u16, 22), try s.refused(flag, bad));
            try std.testing.expectEqualStrings("bad flag: takes 1 or 0", s.said);
        }
    }
    try s.expect(dirty, "0\n");
    try s.expect(mark, "1\n");
    try s.expect(scroll, "1\n");
    // dirty as /index shows it.
    try s.write(dirty, "1\n");
    try s.expect(dirty, "1\n");
    try std.testing.expect(std.mem.indexOf(u8, try s.read("/index"), s.at("{d} text 1 ", .{n})) != null);
    try s.write(dirty, "0");
    try std.testing.expect(std.mem.indexOf(u8, try s.read("/index"), s.at("{d} text 0 ", .{n})) != null);
    try s.write(mark, "0");
    try s.write(scroll, "0");
    try s.expect(mark, "0\n");
    try s.expect(scroll, "0\n");
    try s.write(mark, "1");
    try s.write(scroll, "1");
    try s.expect(mark, "1\n");
    try s.expect(scroll, "1\n");
    // A terminal has no file, so its dirty flag is readable but not writable.
    var t = try Session.initTerm(std.testing.allocator);
    defer t.deinit();
    const term_dirty = t.at("/pane/{d}/dirty", .{try t.focused()});
    try t.expect(term_dirty, "0\n");
    try std.testing.expectEqual(@as(u16, 22), try t.refused(term_dirty, "1"));
}

test "flags: a > into an empty body is one undo step, as into any other" {
    var s = try Session.initFile(std.testing.allocator, "");
    defer s.deinit();
    const n = try s.focused();
    const body = s.at("/pane/{d}/body", .{n});
    try s.replace(body, "fresh\n");
    try s.expect(body, "fresh\n");
    try s.write(s.at("/pane/{d}/ctl", .{n}), "Undo\n");
    try s.expect(body, "");
}

test "flags: a write that changes nothing, an empty range deleted or a range replaced by itself, is no undo step and no new version" {
    var s = try Session.initFile(std.testing.allocator, "abc\ndef\n");
    defer s.deinit();
    const n = try s.focused();
    const body = s.at("/pane/{d}/body", .{n});
    const addr = s.at("/pane/{d}/addr", .{n});
    const data = s.at("/pane/{d}/data", .{n});
    const ctl = s.at("/pane/{d}/ctl", .{n});
    // One real change, so a step made after it would be the one undone.
    try s.write(addr, "1");
    try s.write(data, "abd\n");
    const version = (try s.stat(body)).version;
    // Each as a shell does it: `: > data` after an empty address, `echo
    // abd > data` over the line it holds, and Edit's `s/d/d/`.
    try s.write(addr, "#2,#2");
    const h = try s.hold(data, 1);
    try s.truncate(h);
    s.clunk(h);
    try s.write(addr, "1");
    try s.write(data, "abd\n");
    try s.write(ctl, "Edit ,s/d/d/\n");
    try s.expect(body, "abd\ndef\n");
    try std.testing.expectEqual(version, (try s.stat(body)).version);
    try s.write(ctl, "Undo\n");
    try s.expect(body, "abc\ndef\n");
}

test "flags: an open's writes in a row go in as one edit, seen by the next request" {
    var s = try Session.initFile(std.testing.allocator, "one\n");
    defer s.deinit();
    const n = try s.focused();
    const body = s.at("/pane/{d}/body", .{n});
    const version = (try s.stat(body)).version;
    const h = try s.hold(body, 1);
    for (0..100) |_| try std.testing.expectEqual(@as(u16, 0), try s.writeFid(h, "0123456789\n"));
    try std.testing.expectEqual(@as(usize, 4 + 1100), (try s.read(body)).len);
    try std.testing.expectEqual(version + 1, (try s.stat(body)).version);
    s.clunk(h);
    try s.write(s.at("/pane/{d}/ctl", .{n}), "Undo\n");
    try s.expect(body, "one\n");
    // data inserts at its address go on the same way.
    try s.write(s.at("/pane/{d}/addr", .{n}), "#0");
    const d = try s.hold(s.at("/pane/{d}/data", .{n}), 1);
    _ = try s.writeFid(d, "a");
    _ = try s.writeFid(d, "b");
    s.clunk(d);
    try s.expect(body, "abone\n");
}