summaryrefslogtreecommitdiff
path: root/test/process.zig
blob: ef825ef0b1a2ad8f975a9a3deed6ade2bcbdd309 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
//! The process runner of docs/next-tests.md: a real `pardes`, detached or
//! in a pty (test/e2e_harness.zig's Harness), and what a 9P client sees of
//! it over its socket, with T1's Session method names (test/session.zig), so
//! a test reads alike at either tier. The snap scripts, the process tests
//! (test/process/) and the window's run on it.
const std = @import("std");
const libc = std.c;
const eh = @import("e2e_harness.zig");
const Client = @import("9p_io").Client;

extern "c" fn setenv(name: [*:0]const u8, value: [*:0]const u8, overwrite: c_int) c_int;
extern "c" fn unsetenv(name: [*:0]const u8) c_int;
extern "c" fn execvp(file: [*:0]const u8, argv: [*:null]const ?[*:0]const u8) c_int;
extern "c" fn _exit(status: c_int) noreturn;
extern "c" fn mkdtemp(template: [*:0]u8) ?[*:0]u8;
extern "c" fn system(cmd: [*:0]const u8) c_int;
extern "c" fn realpath(path: [*:0]const u8, resolved: [*]u8) ?[*:0]u8;

/// A running pardes's file tree, dialled by its pid or socket path.
pub const Files = struct {
    arena: std.heap.ArenaAllocator,
    dial_buf: [4096]u8 = undefined,
    dial_len: usize = 0,

    pub fn init(gpa: std.mem.Allocator, to: []const u8) Files {
        var f: Files = .{ .arena = .init(gpa) };
        @memcpy(f.dial_buf[0..to.len], to);
        f.dial_len = to.len;
        return f;
    }

    pub fn deinit(f: *Files) void {
        f.arena.deinit();
    }

    fn dial(f: *const Files) []const u8 {
        return f.dial_buf[0..f.dial_len];
    }

    /// The whole file at `path`, kept until deinit.
    pub fn read(f: *Files, path: []const u8) ![]const u8 {
        const gpa = f.arena.child_allocator;
        const bytes = try Client.read(gpa, f.dial(), path, path);
        defer gpa.free(bytes);
        return f.arena.allocator().dupe(u8, bytes);
    }

    pub fn write(f: *Files, path: []const u8, data: []const u8) !void {
        try Client.write(f.arena.child_allocator, f.dial(), path, data);
    }

    pub fn expect(f: *Files, path: []const u8, want: []const u8) !void {
        try std.testing.expectEqualStrings(want, try f.read(path));
    }

    /// Keys typed at the pane with the keyboard (`/kbdin`'s runes).
    pub fn keys(f: *Files, runes: []const u8) !void {
        try f.write("/kbdin", runes);
    }

    /// A click (1 left, 2 middle, 4 right) `into` cells into the first place
    /// `text` is drawn.
    pub fn click(f: *Files, text: []const u8, into: usize, buttons: u8) !void {
        const col, const row = try f.where(text);
        var line: [64]u8 = undefined;
        const x = col + into;
        try f.write("/mousein", try std.fmt.bufPrint(&line, "m {d} {d} {d}\nm {d} {d} 0\n", .{ x, row, buttons, x, row }));
    }

    /// The screen a frame draws, a line a row.
    // shortcut: Session.screen's twin (test/session.zig, another module);
    // share them when a third copy would be wanted.
    pub fn screen(f: *Files) ![]const u8 {
        const a = f.arena.allocator();
        const json = try std.json.parseFromSliceLeaky(std.json.Value, a, try f.read("/screen"), .{});
        const cols: usize = @intCast(json.object.get("cols").?.integer);
        var out: std.ArrayList(u8) = .empty;
        for (json.object.get("cells").?.array.items, 0..) |cell, i| {
            if (i > 0 and i % cols == 0) try out.append(a, '\n');
            const g = cell.array.items[0].string;
            try out.appendSlice(a, if (g.len == 0) " " else g);
        }
        return out.items;
    }

    /// Where `text` is first drawn, its column and row.
    pub fn where(f: *Files, text: []const u8) !struct { usize, usize } {
        var rows = std.mem.splitScalar(u8, try f.screen(), '\n');
        var row: usize = 0;
        while (rows.next()) |line| : (row += 1) {
            if (std.mem.indexOf(u8, line, text)) |i| return .{ try std.unicode.utf8CountCodepoints(line[0..i]), row };
        }
        std.debug.print("not on the screen: {s}\n", .{text});
        return error.NotOnScreen;
    }

    /// The serial of the pane with the keyboard.
    pub fn focused(f: *Files) !u32 {
        return std.fmt.parseInt(u32, std.mem.trim(u8, try f.read("/focus"), "\n"), 10);
    }

    /// A new pane, made by opening /pane/new; its serial.
    pub fn newPane(f: *Files) !u32 {
        return std.fmt.parseInt(u32, std.mem.trim(u8, try f.read("/pane/new"), "\n"), 10);
    }

    /// A path built from `args`, kept until deinit.
    pub fn at(f: *Files, comptime fmt: []const u8, args: anytype) []const u8 {
        return std.fmt.allocPrint(f.arena.allocator(), fmt, args) catch @panic("out of memory");
    }
};

/// The files of the app a pty harness started.
pub fn of(gpa: std.mem.Allocator, h: *const eh.Harness) Files {
    var digits: [24]u8 = undefined;
    return .init(gpa, std.fmt.bufPrint(&digits, "{d}", .{h.pid}) catch unreachable);
}

/// `pardes --detach=<name>` in a throwaway root that is its HOME, runtime
/// and config directory, as test/fs.py's session started one: no session
/// of the user's is reached. No daemon (PARDES_DAEMON=off, as the pty
/// harness starts one): the process is the session, and nothing outlives it.
pub const Detached = struct {
    pid: libc.pid_t,
    root_buf: [64]u8 = undefined,
    root_len: usize = 0,
    files: Files,

    pub fn start(gpa: std.mem.Allocator, exe: [:0]const u8, name: []const u8) !Detached {
        var d: Detached = .{ .pid = 0, .files = undefined };
        const template = "/tmp/pardes-process-XXXXXX";
        @memcpy(d.root_buf[0..template.len], template);
        d.root_buf[template.len] = 0;
        _ = mkdtemp(d.root_buf[0..template.len :0]) orelse return error.NoTempDir;
        d.root_len = template.len;
        const dir = d.root();
        var buf: [4096]u8 = undefined;
        const fixture = try std.fmt.bufPrintSentinel(&buf, "{s}/{s}.txt", .{ dir, name }, 0);
        try eh.writeFile(fixture, "initial\n");
        var sock: [4096]u8 = undefined;
        // The session's socket, as its 9P service links it (src/9p_io.zig).
        const socket = try std.fmt.bufPrint(&sock, "{s}/9p/pardes/{s}", .{ dir, name });
        var arg_buf: [256]u8 = undefined;
        const detach = try std.fmt.bufPrintSentinel(&arg_buf, "--detach={s}", .{name}, 0);
        var env_buf: [3][4096]u8 = undefined;
        const root_z = try std.fmt.bufPrintSentinel(&env_buf[0], "{s}", .{dir}, 0);
        const config = try std.fmt.bufPrintSentinel(&env_buf[1], "{s}/config", .{dir}, 0);
        const dump = try std.fmt.bufPrintSentinel(&env_buf[2], "{s}/{s}.dump.zon", .{ dir, name }, 0);
        var err_buf: [4096]u8 = undefined;
        const err_log = try std.fmt.bufPrintSentinel(&err_buf, "{s}/stderr", .{dir}, 0);
        // The build hands the binary over by a relative path, and the child
        // runs in the root.
        var exe_buf: [4096]u8 = undefined;
        const exe_abs = realpath(exe, &exe_buf) orelse return error.NoBinary;
        const pid = libc.fork();
        if (pid < 0) return error.ForkFailed;
        if (pid == 0) {
            // What a session of the caller's left in the environment, and a
            // pager of theirs, are not the session under test's.
            for ([_][*:0]const u8{ "PARDES_PID", "PARDES_9P", "PARDES_PANE", "PARDES_MOUNT", "PAGER" }) |v| _ = unsetenv(v);
            for ([_][2][*:0]const u8{
                .{ "HOME", root_z },             .{ "XDG_RUNTIME_DIR", root_z }, .{ "XDG_CONFIG_HOME", config },
                .{ "PARDES_NOTIME", "1" },       .{ "PARDES_DUMP", dump },        .{ "PARDES_LSP_RS", "" },
                .{ "PARDES_LSP_C", "" },         .{ "PARDES_LSP_GO", "" },        .{ "PARDES_LSP_TS", "" },
                .{ "PARDES_LSP_PY", "" },         .{ "PARDES_DAEMON", "off" },
            }) |kv| if (setenv(kv[0], kv[1], 1) != 0) _exit(126);
            if (libc.chdir(root_z) != 0) _exit(126);
            const fd = libc.open(err_log, .{ .ACCMODE = .WRONLY, .CREAT = true, .TRUNC = true }, @as(libc.mode_t, 0o644));
            if (fd >= 0) _ = libc.dup2(fd, 2);
            const argv = [_:null]?[*:0]const u8{ exe_abs, detach, fixture };
            _ = execvp(exe_abs, &argv);
            _exit(127);
        }
        d.pid = pid;
        errdefer {
            d.stop();
            d.removeRoot();
        }
        const deadline = eh.nowMs() + 10_000;
        var sock_z: [4096]u8 = undefined;
        const socket_z = try std.fmt.bufPrintSentinel(&sock_z, "{s}", .{socket}, 0);
        while (libc.access(socket_z, 0) != 0) {
            var status: c_int = 0;
            if (libc.waitpid(pid, &status, std.c.W.NOHANG) == pid) {
                d.pid = 0;
                var said: [4096]u8 = undefined;
                const fd = libc.open(err_log, .{}, @as(libc.mode_t, 0));
                const n = if (fd >= 0) libc.read(fd, &said, said.len) else 0;
                if (fd >= 0) _ = libc.close(fd);
                std.debug.print("the session exited, status {d}: {s}\n", .{ status, said[0..@intCast(@max(n, 0))] });
                return error.SessionExited;
            }
            if (eh.nowMs() > deadline) return error.NoSocket;
            var ts: libc.timespec = .{ .sec = 0, .nsec = 5 * std.time.ns_per_ms };
            _ = libc.nanosleep(&ts, null);
        }
        d.files = .init(gpa, socket);
        return d;
    }

    pub fn root(d: *const Detached) []const u8 {
        return d.root_buf[0..d.root_len];
    }

    /// Ended (SIGTERM, then SIGKILL after 5 s), its root removed.
    pub fn deinit(d: *Detached) void {
        d.files.deinit();
        d.stop();
        d.removeRoot();
    }

    fn removeRoot(d: *Detached) void {
        var cmd: [128]u8 = undefined;
        if (std.fmt.bufPrintSentinel(&cmd, "rm -rf -- '{s}'", .{d.root()}, 0)) |c| {
            _ = system(c);
        } else |_| {}
    }

    fn stop(d: *Detached) void {
        if (d.pid <= 0) return;
        _ = libc.kill(d.pid, libc.SIG.TERM);
        const deadline = eh.nowMs() + 5_000;
        var status: c_int = 0;
        while (libc.waitpid(d.pid, &status, std.c.W.NOHANG) != d.pid) {
            if (eh.nowMs() > deadline) {
                _ = libc.kill(d.pid, libc.SIG.KILL);
                _ = libc.waitpid(d.pid, &status, 0);
                break;
            }
            var ts: libc.timespec = .{ .sec = 0, .nsec = 10 * std.time.ns_per_ms };
            _ = libc.nanosleep(&ts, null);
        }
        d.pid = 0;
    }
};