blob: 0ed0b66d4cf0f6f19ceb7784fdcecfbe37da10f2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
; Vendored from helix (https://github.com/helix-editor/helix) at 278b24389:
; runtime/queries/c/indents.scm.
; Licensed under the Mozilla Public License 2.0 (vendor/queries/helix.LICENSE,
; https://mozilla.org/MPL/2.0/).
[
(compound_statement)
(declaration_list)
(field_declaration_list)
(enumerator_list)
(parameter_list)
(init_declarator)
(expression_statement)
] @indent
[
"case"
"default"
"}"
"]"
")"
] @outdent
; Single statement after if/while/for/do without braces. Capture the body child
; naturally; on a typed newline the engine descends into it (no wrapper trick).
(if_statement
consequence: (_) @indent
(#not-kind-eq? @indent "compound_statement")
(#set! "scope" "header"))
(while_statement
body: (_) @indent
(#not-kind-eq? @indent "compound_statement")
(#set! "scope" "header"))
(do_statement
body: (_) @indent
(#not-kind-eq? @indent "compound_statement")
(#set! "scope" "header"))
(for_statement
body: (_) @indent
(#not-kind-eq? @indent "compound_statement")
(#set! "scope" "header"))
(parameter_list
. (parameter_declaration) @anchor
) @align
(argument_list
. (_) @anchor
) @align
; These are a bit opinionated since some people just indent binary/ternary expressions spanning multiple lines.
; Since they are only triggered when a newline is inserted into an already complete binary/ternary expression,
; this should happen rarely, so it is not a big deal either way.
; Additionally, adding these queries has the advantage of preventing such continuation lines from being used
; as the baseline when the `hybrid` indent heuristic is used (which is desirable since their indentation is so inconsistent).
(binary_expression
) @anchor @align
(conditional_expression
"?" @anchor
) @align
|