summaryrefslogtreecommitdiff
path: root/examples/live/test/grammar.zig
blob: 2fa982f3205f61b5ccbcece56c9dd467cf17e017 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
//! The language's grammar (grammar/grammar.js, its parser.c compiled into
//! the sketch) against src/Lang.zig, which compiles the text: they must
//! agree on what is well formed, or what is coloured and walked would not
//! be the program that plays.
const std = @import("std");
const app = @import("app");
const Lang = @import("Lang");
const pe = @import("pardes-editor");

test "the grammar and Lang.zig agree: both take a program, both refuse a broken line; what only Lang.zig refuses is its meaning" {
    const parser = pe.syntax.ts.Parser.create();
    defer parser.destroy();
    try parser.setLanguage(app.tree_sitter_live());
    const Case = struct { text: []const u8, grammar: bool, lang: bool };
    for ([_]Case{
        .{ .text = Lang.survey, .grammar = true, .lang = true },
        .{ .text = "out = sin(tau * 220 * t) * 0.3\ncolor = hsv(x, 0.5, y)", .grammar = true, .lang = true },
        .{ .text = "\n  # nothing\n a = 1 + 2 * -t / 4 - (5 - -6) # trailing\n\nout = a + 1e-3\n", .grammar = true, .lang = true },
        // broken lines: both refuse
        .{ .text = "out = sin(tau * 220 * t * 0.3", .grammar = false, .lang = false },
        .{ .text = "out = 1 +", .grammar = false, .lang = false },
        .{ .text = "= 1", .grammar = false, .lang = false },
        .{ .text = "out 1", .grammar = false, .lang = false },
        .{ .text = "out", .grammar = false, .lang = false },
        .{ .text = "out = * 2", .grammar = false, .lang = false },
        .{ .text = "out = 1 2", .grammar = false, .lang = false },
        .{ .text = "out = sin(1 2)", .grammar = false, .lang = false },
        .{ .text = "out = 1.2.3", .grammar = false, .lang = false },
        .{ .text = "out = 1 $ 2", .grammar = false, .lang = false },
        .{ .text = "out = (1 + 2))", .grammar = false, .lang = false },
        // well formed, but meaning nothing: only Lang.zig knows its names,
        // builtins and arities, and the problem it shows is the one drawn
        .{ .text = "out = kick\nkick = 1", .grammar = true, .lang = false },
        .{ .text = "a = 1\na = 2", .grammar = true, .lang = false },
        .{ .text = "sin = 1", .grammar = true, .lang = false },
        .{ .text = "out = sin", .grammar = true, .lang = false },
        .{ .text = "out = foo(2)", .grammar = true, .lang = false },
        .{ .text = "out = mix(1, 2)", .grammar = true, .lang = false },
        .{ .text = "out = rgb(1, 1, 1)", .grammar = true, .lang = false },
        .{ .text = "a = 1\nout = a(2)", .grammar = true, .lang = false },
    }) |case| {
        const tree = parser.parseString(case.text, null) orelse return error.NoTree;
        defer tree.destroy();
        const lang = Lang.compile(case.text, null) == .program;
        std.testing.expectEqual(case.grammar, !tree.rootNode().hasError()) catch |e| {
            std.debug.print("the grammar on {s}\n", .{case.text});
            return e;
        };
        std.testing.expectEqual(case.lang, lang) catch |e| {
            std.debug.print("Lang.zig on {s}\n", .{case.text});
            return e;
        };
    }
}