summaryrefslogtreecommitdiff
path: root/examples/micscope/shaders/tuner_difference.comp
blob: c7d1b6e02e83b2dd4040ccfa59276fc2e13b6800 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
#version 450
#extension GL_GOOGLE_include_directive : require
// YIN's difference function for tuner.comp, spread over many workgroups:
// d(tau) = sum over the newest W samples of (x[j] - x[j - tau])^2. Each
// workgroup takes LAGS_PER_GROUP lags, with THREADS / LAGS_PER_GROUP
// threads summing every so-many term of each, then adding up.
layout(local_size_x = 256) in;

#include "TunerParams.glsl"

layout(set = 0, binding = 0) readonly buffer Tape { float tape[]; };
layout(set = 1, binding = 0) buffer Difference { float d[]; };

// Match layouts.zig and tuner.comp.
const uint W = 2048;
const uint LAGS = 1700;
const uint THREADS = 256;
const uint LAGS_PER_GROUP = 16;
const uint PER_LAG = THREADS / LAGS_PER_GROUP;

shared float x[W + LAGS];
shared float partial[THREADS];

void main() {
    uint t = gl_LocalInvocationID.x;
    int first = int(u.end) - int(W + LAGS);
    for (uint i = t; i < W + LAGS; i += THREADS) {
        int at = first + int(i);
        x[i] = at >= 0 && at < int(u.samples) ? tape[u.offset + uint(at)] : 0.0;
    }
    barrier();

    uint tau = gl_WorkGroupID.x * LAGS_PER_GROUP + t / PER_LAG;
    uint lane = t % PER_LAG;
    float sum = 0.0;
    if (tau < LAGS) {
        for (uint j = lane; j < W; j += PER_LAG) {
            float diff = x[LAGS + j] - x[LAGS + j - tau];
            sum += diff * diff;
        }
    }
    partial[t] = sum;
    barrier();
    for (uint stride = PER_LAG / 2u; stride > 0u; stride >>= 1u) {
        if (lane < stride) partial[t] += partial[t + stride];
        barrier();
    }
    if (lane == 0u && tau < LAGS) d[tau] = partial[t];
}