summaryrefslogtreecommitdiff
path: root/src/gpu/shaders/ui.frag.glsl
blob: 7f70629a7c1726d436399a0957803d3addbd3a18 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
#version 450

// Sample the glyph atlas (R = coverage 0..1) and mix the cell's bg up to its fg
// by that coverage. Output is PREMULTIPLIED: an opaque cell is unchanged.
// WindowOpacity changes only the ground's coverage, never the glyph's ink.

layout(set = 2, binding = 0) uniform sampler2D u_atlas;
layout(std140, set = 3, binding = 0) uniform UiUniforms {
    float background_opacity;
} u_ui;

layout(location = 0) in vec2 v_uv;
layout(location = 1) in vec3 v_fg;
layout(location = 2) in vec3 v_bg;
layout(location = 4) flat in uint v_effect;
layout(location = 5) flat in vec4 v_clip;

layout(location = 0) out vec4 o_col;

void main() {
    if (v_clip.z >= v_clip.x && (gl_FragCoord.x < v_clip.x || gl_FragCoord.x >= v_clip.z ||
        gl_FragCoord.y < v_clip.y || gl_FragCoord.y >= v_clip.w)) discard;
    float a = texture(u_atlas, v_uv).r;
    // A block cursor is foreground chrome even though its fill occupies the
    // cell background: keep it visible at WindowOpacity 0. Otherwise the
    // ground's coverage is the setting's. The flag is shared with
    // ui.vert.glsl and src/gui/gui.zig.
    float bgA = (v_effect & 0x20000000u) != 0u ? 1.0 : clamp(u_ui.background_opacity, 0.0, 1.0);

    // Ink over ground, both premultiplied: v_fg*a + (v_bg*bgA)*(1-a), which is
    // mix() with the ground already premultiplied. At bgA = 1 that is exactly
    // the mix(v_bg, v_fg, a) at alpha 1 this shader always wrote.
    vec4 under = vec4(v_bg * bgA, bgA);
    vec4 cell = vec4(mix(under.rgb, v_fg, a), mix(under.a, 1.0, a));

    // FreeType's hinted grayscale bitmap is already the intended coverage.
    // Preserve it exactly; weight-changing gamma hacks blur small stems.
    o_col = cell;
}