summaryrefslogtreecommitdiff
path: root/src/host/audio.zig
blob: bf5fdc449b44cbffcbc4426971a666e38e185f9d (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
//! Sound: decoded clips played by reconciled voices, raw streams the sketch
//! fills itself, and the microphone, open while declared. The audio thread
//! only ever sees SDL's own copies of the samples; sketch code and memory
//! never run on it.
const std = @import("std");
const c = @import("c");
const abi = @import("abi");
const memory = @import("memory.zig");

pub const sample_rate = 48_000;
const spec: c.SDL_AudioSpec = .{ .format = c.SDL_AUDIO_F32, .channels = 1, .freq = sample_rate };
/// A device block plus the next frame; 512 samples can underrun at 60 Hz.
const queue_samples = 2048;
/// How far a group's gain moves a sample toward a new one: a full swing
/// takes 10 ms, so a gain set in a step does not click.
const gain_step = 1.0 / 480.0;

pub const Audio = struct {
    gpa: std.mem.Allocator,
    device: c.SDL_AudioDeviceID = 0,
    /// Mixed voices.
    voices_out: ?*c.SDL_AudioStream = null,
    clips: std.ArrayList([]f32) = .empty,
    paths: std.StringHashMapUnmanaged(abi.Audio) = .empty,
    voices: std.ArrayList(Playing) = .empty,
    /// Each group's gain as declared this frame, and as the mix has got to.
    gains: [8]f32 = @splat(1),
    heard_gains: [8]f32 = @splat(1),
    streams: std.ArrayList(Stream) = .empty,
    status: std.ArrayList(abi.Stream) = .empty,
    scope: Scope = .{},
    /// The default recording device, bound to this stream while declared.
    microphone: ?*c.SDL_AudioStream = null,
    listening: bool = false,
    /// Set when opening failed, so it is tried once per declaration.
    deaf: bool = false,

    const Playing = struct {
        voice: abi.Voice,
        /// Where in the sound, in its samples: fractional when `rate` is.
        cursor: f64 = 0,
        done: bool = false,
        seen: bool = true,
        /// Mixed since a script last asked (`expect-audio`).
        sounded: bool = false,
    };
    const Stream = struct { key: u32, out: *c.SDL_AudioStream, pushed: u64 = 0 };

    pub fn open(self: *Audio) !void {
        const device = c.SDL_OpenAudioDevice(c.SDL_AUDIO_DEVICE_DEFAULT_PLAYBACK, &spec);
        if (device == 0) return error.OpenAudio;
        self.device = device;
        self.voices_out = try self.bind();
        self.scope.attach(device) catch {};
    }

    pub fn deinit(self: *Audio) void {
        if (self.microphone) |m| c.SDL_DestroyAudioStream(m);
        self.scope.deinit();
        for (self.streams.items) |s| c.SDL_DestroyAudioStream(s.out);
        if (self.voices_out) |s| c.SDL_DestroyAudioStream(s);
        if (self.device != 0) c.SDL_CloseAudioDevice(self.device);
        for (self.clips.items) |samples| self.gpa.free(samples);
        var keys = self.paths.keyIterator();
        while (keys.next()) |key| self.gpa.free(key.*);
        self.paths.deinit(self.gpa);
        self.clips.deinit(self.gpa);
        self.voices.deinit(self.gpa);
        self.streams.deinit(self.gpa);
        self.status.deinit(self.gpa);
    }

    fn bind(self: *Audio) !*c.SDL_AudioStream {
        const out = c.SDL_CreateAudioStream(&spec, &spec) orelse return error.OpenAudio;
        errdefer c.SDL_DestroyAudioStream(out);
        if (!c.SDL_BindAudioStream(self.device, out)) return error.OpenAudio;
        return out;
    }

    /// `.none` when the file is missing or unreadable, remembered so the
    /// warning prints once.
    pub fn load(self: *Audio, path: []const u8) abi.Audio {
        if (self.paths.get(path)) |audio| return audio;
        const audio: abi.Audio = if (decodeFile(self.gpa, path)) |samples| self.add(samples) else |err| blk: {
            std.log.warn("sound {s}: {t}", .{ path, err });
            break :blk .none;
        };
        const key = self.gpa.dupe(u8, path) catch return audio;
        self.paths.put(self.gpa, key, audio) catch self.gpa.free(key);
        return audio;
    }

    /// `.none` when `wav` does not decode.
    pub fn decode(self: *Audio, wav: []const u8) abi.Audio {
        return self.add(decodeBytes(self.gpa, wav) catch return .none);
    }

    /// A copy of `samples`; `.none` if one is not finite.
    pub fn new(self: *Audio, samples: []const f32) abi.Audio {
        for (samples) |v| if (!std.math.isFinite(v)) return .none;
        return self.add(self.gpa.dupe(f32, samples) catch return .none);
    }

    fn add(self: *Audio, samples: []f32) abi.Audio {
        self.clips.append(self.gpa, samples) catch {
            self.gpa.free(samples);
            return .none;
        };
        return @fromBackingInt(@intCast(self.clips.items.len));
    }

    pub fn samplesOf(self: *Audio, audio: abi.Audio) []const f32 {
        const index = @backingInt(audio);
        if (index == 0 or index > self.clips.items.len) return &.{};
        return self.clips.items[index - 1];
    }

    pub fn beginFrame(self: *Audio) void {
        for (self.voices.items) |*v| v.seen = false;
        self.gains = @splat(1);
        self.listening = false;
    }

    /// The microphone was declared this frame.
    pub fn listen(self: *Audio) void {
        self.listening = true;
    }

    /// What the microphone heard since the last call, into `arena`.
    pub fn record(self: *Audio, arena: std.mem.Allocator) []const f32 {
        const m = self.microphone orelse return &.{};
        const available = c.SDL_GetAudioStreamAvailable(m);
        if (available <= 0) return &.{};
        const samples = arena.alloc(f32, @as(usize, @intCast(available)) / @sizeOf(f32)) catch return &.{};
        const got = c.SDL_GetAudioStreamData(m, samples.ptr, @intCast(samples.len * @sizeOf(f32)));
        if (got <= 0) return &.{};
        return samples[0 .. @as(usize, @intCast(got)) / @sizeOf(f32)];
    }

    /// Opens or closes the microphone to match this frame's declaration.
    fn reconcileMicrophone(self: *Audio) void {
        if (!self.listening) {
            if (self.microphone) |m| c.SDL_DestroyAudioStream(m);
            self.microphone = null;
            self.deaf = false;
            return;
        }
        if (self.microphone != null or self.deaf) return;
        const m = c.SDL_OpenAudioDeviceStream(c.SDL_AUDIO_DEVICE_DEFAULT_RECORDING, &spec, null, null) orelse {
            std.log.warn("microphone: {s}", .{c.SDL_GetError()});
            self.deaf = true;
            return;
        };
        if (!c.SDL_ResumeAudioStreamDevice(m)) std.log.warn("microphone: {s}", .{c.SDL_GetError()});
        self.microphone = m;
    }

    /// Reconciles one declared voice with what is playing.
    pub fn declare(self: *Audio, voice: abi.Voice) void {
        for (self.voices.items) |*playing| {
            if (playing.voice.key != voice.key) continue;
            const restart = playing.voice.serial != voice.serial or playing.voice.audio != voice.audio;
            playing.voice = voice;
            playing.seen = true;
            if (restart) {
                playing.cursor = 0;
                playing.done = false;
            }
            return;
        }
        self.voices.append(self.gpa, .{ .voice = voice }) catch {};
    }

    pub fn push(self: *Audio, key: u32, samples: []const f32, clear: bool) void {
        const s = self.streamFor(key) orelse return;
        if (clear) {
            _ = c.SDL_ClearAudioStream(s.out);
            s.pushed = 0;
        }
        if (samples.len == 0) return;
        if (c.SDL_PutAudioStreamData(s.out, samples.ptr, @intCast(samples.len * @sizeOf(f32)))) s.pushed += samples.len;
    }

    fn streamFor(self: *Audio, key: u32) ?*Stream {
        for (self.streams.items) |*s| if (s.key == key) return s;
        if (self.device == 0) return null;
        const out = self.bind() catch return null;
        self.streams.append(self.gpa, .{ .key = key, .out = out }) catch {
            c.SDL_DestroyAudioStream(out);
            return null;
        };
        return &self.streams.items[self.streams.items.len - 1];
    }

    /// Drops undeclared voices, keeps the voice mix queued ahead, and opens
    /// or closes the microphone.
    pub fn endFrame(self: *Audio) void {
        self.reconcileMicrophone();
        var i: usize = 0;
        while (i < self.voices.items.len) {
            if (self.voices.items[i].seen) i += 1 else _ = self.voices.swapRemove(i);
        }
        const out = self.voices_out orelse return;
        const queued = c.SDL_GetAudioStreamQueued(out);
        if (queued < 0) return;
        const needed = queue_samples -| @as(usize, @intCast(queued)) / @sizeOf(f32);
        var buffer: [queue_samples]f32 = undefined;
        const count = self.mix(buffer[0..needed]);
        if (count != 0) _ = c.SDL_PutAudioStreamData(out, &buffer, @intCast(count * @sizeOf(f32)));
    }

    /// Mixes live voices into `output`; returns how many samples were written,
    /// stopping early once every voice has finished. A voice at another
    /// rate is resampled by linear interpolation between its neighbours
    /// (at rate 1 it is its samples, exactly).
    pub fn mix(self: *Audio, output: []f32) usize {
        var count: usize = 0;
        for (output) |*sample| {
            var sum: f32 = 0;
            var alive = false;
            for (&self.heard_gains, self.gains) |*heard, gain| heard.* += std.math.clamp(gain - heard.*, -gain_step, gain_step);
            for (self.voices.items) |*playing| {
                if (playing.done) continue;
                const samples = self.samplesOf(playing.voice.audio);
                const len: f64 = @floatFromInt(samples.len);
                // Also ends a cursor an infinite or NaN rate made.
                if (!(playing.cursor < len)) {
                    playing.done = true;
                    continue;
                }
                alive = true;
                playing.sounded = true;
                const v = playing.voice;
                const i: usize = @intFromFloat(playing.cursor);
                const t: f32 = @floatCast(playing.cursor - @floor(playing.cursor));
                const next = if (i + 1 < samples.len) samples[i + 1] else if (v.loop) samples[0] else 0;
                const at = if (t == 0) samples[i] else samples[i] + (next - samples[i]) * t;
                const edge = @min(i + 1, samples.len - i);
                const fade: f32 = if (v.fade == 0) 1 else @as(f32, @floatFromInt(@min(edge, v.fade))) / @as(f32, @floatFromInt(v.fade));
                sum += at * v.volume * self.heard_gains[v.group] * fade;
                playing.cursor += @max(v.rate, 0);
                if (playing.cursor >= len and v.loop) playing.cursor = @mod(playing.cursor, len);
            }
            if (!alive) break;
            sample.* = limit(sum);
            count += 1;
        }
        return count;
    }

    /// Whether voice `key` was mixed since the last call: for scripts.
    pub fn sounded(self: *Audio, key: u32) bool {
        for (self.voices.items) |*playing| if (playing.voice.key == key) {
            defer playing.sounded = false;
            return playing.sounded;
        };
        return false;
    }

    pub fn streamStatus(self: *Audio) []const abi.Stream {
        self.status.clearRetainingCapacity();
        for (self.streams.items) |s| {
            const queued = c.SDL_GetAudioStreamQueued(s.out);
            self.status.append(self.gpa, .{ .key = s.key, .queued = @intCast(@divFloor(@max(queued, 0), @sizeOf(f32))), .pushed = s.pushed }) catch {};
        }
        return self.status.items;
    }
};

/// Where the voice mix stops being passed through: -2.5 dBFS. Quieter
/// mixes keep their true volume to the bit; a clip normalised to full scale
/// only has its peaks bent (1 comes out at 0.875).
pub const knee = 0.75;

/// The voice mix, bounded however many voices sound at once: unity gain up
/// to the knee, then `knee + (1 - knee)·u/(1 + u)` with `u` how far past the
/// knee in units of the room left, which meets the line at the knee with
/// its slope (1) and tends to 1. (With a knee of 0 it is the old
/// `x/(1 + |x|)`.) Written `1 - 1/(1 + u)` so that every step rounds
/// monotonically and infinity comes out at 1. No state, no lookahead.
pub fn limit(x: f32) f32 {
    const a = @abs(x);
    if (a <= knee) return x;
    const u = (a - knee) / (1 - knee);
    return std.math.copysign(knee + (1 - knee) * (1 - 1 / (1 + u)), x);
}

/// WAV, FLAC or Ogg Vorbis, by content (see `vendor/codecs.h`).
fn decodeBytes(gpa: std.mem.Allocator, bytes: []const u8) ![]f32 {
    var channels: u32 = 0;
    var rate: u32 = 0;
    var frames: u64 = 0;
    const raw = c.sketchbook_decode_audio(bytes.ptr, bytes.len, &channels, &rate, &frames) orelse return error.DecodeAudio;
    defer c.sketchbook_free_audio(raw);
    if (rate == 0 or rate > 192000 or channels == 0 or channels > 8 or frames == 0 or frames > @as(u64, rate) * 600) return error.UnsupportedSoundFormat;
    const from: c.SDL_AudioSpec = .{ .format = c.SDL_AUDIO_F32, .channels = @intCast(channels), .freq = @intCast(rate) };
    return convert(gpa, &from, std.mem.sliceAsBytes(raw[0..@intCast(frames * channels)]));
}

fn decodeFile(gpa: std.mem.Allocator, path: []const u8) ![]f32 {
    const bytes = memory.mapReadOnly(path);
    if (bytes.len == 0) return error.OpenSoundFile;
    defer std.posix.munmap(bytes);
    return decodeBytes(gpa, bytes);
}

/// To host format: f32 mono at `sample_rate`, all finite.
fn convert(gpa: std.mem.Allocator, from: *const c.SDL_AudioSpec, data: []const u8) ![]f32 {
    if (data.len == 0 or data.len > std.math.maxInt(c_int)) return error.InvalidAudioLength;
    var out: [*c]u8 = null;
    var out_len: c_int = 0;
    if (!c.SDL_ConvertAudioSamples(from, data.ptr, @intCast(data.len), &spec, &out, &out_len)) return error.ConvertAudio;
    defer c.SDL_free(out);
    if (out_len <= 0 or @mod(out_len, 4) != 0) return error.InvalidAudioLength;
    const samples = @as([*]const f32, @ptrCast(@alignCast(out)))[0..@intCast(@divExact(out_len, 4))];
    for (samples) |v| if (!std.math.isFinite(v)) return error.InvalidAudioSample;
    return gpa.dupe(f32, samples);
}

/// A read-only tap of the device's final mix, for the sound overlay.
pub const Scope = struct {
    mutex: ?*c.SDL_Mutex = null,
    device: c.SDL_AudioDeviceID = 0,
    ring: [512]f32 = @splat(0),
    cursor: usize = 0,
    rate: u32 = sample_rate,

    pub fn attach(self: *Scope, device: c.SDL_AudioDeviceID) !void {
        self.mutex = c.SDL_CreateMutex() orelse return error.ScopeMutex;
        if (!c.SDL_SetAudioPostmixCallback(device, callback, self)) return error.ScopeCallback;
        self.device = device;
    }
    pub fn deinit(self: *Scope) void {
        // SDL waits for a callback in flight before removing it.
        if (self.device != 0) _ = c.SDL_SetAudioPostmixCallback(self.device, null, null);
        if (self.mutex) |m| c.SDL_DestroyMutex(m);
        self.* = .{};
    }
    /// Oldest first.
    pub fn snapshot(self: *Scope) [512]f32 {
        var result: [512]f32 = @splat(0);
        const m = self.mutex orelse return result;
        c.SDL_LockMutex(m);
        defer c.SDL_UnlockMutex(m);
        for (&result, 0..) |*s, i| s.* = self.ring[(self.cursor + i) % self.ring.len];
        return result;
    }
    fn callback(userdata: ?*anyopaque, s: [*c]const c.SDL_AudioSpec, buffer: [*c]f32, bytes: c_int) callconv(.c) void {
        const self: *Scope = @ptrCast(@alignCast(userdata orelse return));
        if (s == null or s.*.channels <= 0 or bytes <= 0) return;
        const m = self.mutex orelse return;
        // Dropping one picture beats blocking the audio thread.
        if (!c.SDL_TryLockMutex(m)) return;
        defer c.SDL_UnlockMutex(m);
        const channels: usize = @intCast(s.*.channels);
        const frames = @as(usize, @intCast(bytes)) / @sizeOf(f32) / channels;
        self.rate = @intCast(s.*.freq);
        for (0..frames) |i| {
            self.ring[self.cursor] = buffer[i * channels];
            self.cursor = (self.cursor + 1) % self.ring.len;
        }
    }
};

test "voices reconcile: one-shots finish and stay silent, new serials restart, undeclared keys stop" {
    var audio: Audio = .{ .gpa = std.testing.allocator };
    defer audio.deinit();
    const clip = audio.add(try std.testing.allocator.dupe(f32, &.{ 0.5, 0.5, 0.5 }));
    var out: [8]f32 = undefined;
    audio.beginFrame();
    audio.declare(.{ .key = 1, .audio = clip });
    try std.testing.expectEqual(@as(usize, 3), audio.mix(&out));
    audio.beginFrame();
    audio.declare(.{ .key = 1, .audio = clip });
    try std.testing.expectEqual(@as(usize, 0), audio.mix(&out));
    audio.beginFrame();
    audio.declare(.{ .key = 1, .audio = clip, .serial = 1 });
    try std.testing.expectEqual(@as(usize, 3), audio.mix(&out));
    audio.beginFrame();
    audio.declare(.{ .key = 2, .audio = clip, .loop = true });
    audio.endFrame();
    try std.testing.expectEqual(@as(usize, 1), audio.voices.items.len);
    try std.testing.expectEqual(@as(usize, 8), audio.mix(&out));
}

test "voices play made sounds: copied, and refused when not finite" {
    var audio: Audio = .{ .gpa = std.testing.allocator };
    defer audio.deinit();
    var made = [_]f32{ 0.25, -0.25 };
    const sound = audio.new(&made);
    made[0] = 1;
    try std.testing.expectEqualSlices(f32, &.{ 0.25, -0.25 }, audio.samplesOf(sound));
    try std.testing.expectEqual(abi.Audio.none, audio.new(&.{ 0, std.math.nan(f32) }));
    try std.testing.expectEqual(abi.Audio.none, audio.new(&.{std.math.inf(f32)}));
}

test "the mixer passes the mix through below the knee and limits it to 1 above, rising" {
    // Identity to the bit: every 997th float from 0 to the knee, both signs.
    const knee_bits: u32 = @bitCast(@as(f32, knee));
    var bits: u32 = 0;
    while (bits <= knee_bits) : (bits += 997) {
        const x: f32 = @bitCast(bits);
        try std.testing.expectEqual(@as(u32, @bitCast(x)), @as(u32, @bitCast(limit(x))));
        try std.testing.expectEqual(@as(u32, @bitCast(-x)), @as(u32, @bitCast(limit(-x))));
    }
    try std.testing.expectEqual(@as(f32, knee), limit(knee));
    // Rising and at most 1, from the knee's neighbourhood (every float) to
    // infinity (every 101st), and odd.
    var last = limit(@bitCast(knee_bits - 100_000));
    bits = knee_bits - 100_000;
    const inf_bits: u32 = @bitCast(std.math.inf(f32));
    while (bits <= inf_bits) : (bits += if (bits < knee_bits + 100_000) 1 else 101) {
        const x: f32 = @bitCast(bits);
        const y = limit(x);
        try std.testing.expect(y >= last and y <= 1);
        try std.testing.expectEqual(-y, limit(-x));
        last = y;
    }
    try std.testing.expectEqual(@as(f32, 1), limit(std.math.inf(f32)));
    // Slope 1 on both sides of the knee, and what a full-scale peak becomes.
    const h = 1e-3;
    try std.testing.expectApproxEqAbs(@as(f32, 1), (limit(knee + h) - limit(knee)) / h, 0.01);
    try std.testing.expectEqual(@as(f32, 0.875), limit(1));
}

test "voices at another rate are resampled linearly, and a group's gain scales its voices smoothly" {
    var audio: Audio = .{ .gpa = std.testing.allocator };
    defer audio.deinit();
    const clip = audio.new(&.{ 0, 0.1, 0.2, 0.3 });
    var out: [1024]f32 = undefined;
    // Half speed: twice as long, the halves interpolated (the last toward
    // silence); double speed: every other sample.
    audio.declare(.{ .key = 1, .audio = clip, .rate = 0.5 });
    try std.testing.expectEqual(@as(usize, 8), audio.mix(&out));
    for ([_]f32{ 0, 0.05, 0.1, 0.15, 0.2, 0.25, 0.3, 0.15 }, out[0..8]) |want, got| try std.testing.expectApproxEqAbs(want, got, 1e-6);
    audio.declare(.{ .key = 1, .audio = clip, .rate = 2, .serial = 1 });
    try std.testing.expectEqual(@as(usize, 2), audio.mix(&out));
    try std.testing.expectEqualSlices(f32, &.{ 0, 0.2 }, out[0..2]);
    // Rate 0 holds it; an infinite rate ends it.
    audio.declare(.{ .key = 1, .audio = clip, .rate = 0, .serial = 2 });
    try std.testing.expectEqual(@as(usize, 3), audio.mix(out[0..3]));
    audio.declare(.{ .key = 1, .audio = clip, .rate = std.math.inf(f32), .serial = 3 });
    try std.testing.expectEqual(@as(usize, 1), audio.mix(&out));

    // A looping voice in group 1 and one in group 0, at 0.25 each: group 1
    // set to 0.5 glides there in 10 ms and stays; group 0 is untouched.
    const level = audio.new(&.{0.25});
    audio.beginFrame();
    audio.declare(.{ .key = 1, .audio = level, .loop = true, .group = 1 });
    audio.declare(.{ .key = 2, .audio = level, .loop = true });
    audio.gains[1] = 0.5;
    try std.testing.expectEqual(out.len, audio.mix(&out));
    try std.testing.expect(out[0] < 0.5 and out[0] > 0.49);
    try std.testing.expect(out[100] > out[200] and out[200] > out[400]);
    try std.testing.expectEqual(@as(f32, 0.375), out[480]);
    try std.testing.expectEqual(@as(f32, 0.375), out[1023]);
    // Undeclared next frame: back to 1, as smoothly.
    audio.beginFrame();
    audio.declare(.{ .key = 1, .audio = level, .loop = true, .group = 1 });
    audio.declare(.{ .key = 2, .audio = level, .loop = true });
    try std.testing.expectEqual(out.len, audio.mix(&out));
    try std.testing.expect(out[0] > 0.375 and out[0] < 0.38);
    try std.testing.expectEqual(@as(f32, 0.5), out[1023]);
}