summaryrefslogtreecommitdiff
path: root/src/scope/shaders/spectrogram.frag
blob: 9cb5e3dd13f24969225f8e4878bddc6d5cbaa06e (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
#version 450
#extension GL_GOOGLE_include_directive : require
// The spectrogram (spectrogram.comp): time across, as the waveform above
// it, log frequency up, each level through a heat gradient (inferno:
// black, violet, red, orange, pale yellow), with the playhead.
layout(location = 0) out vec4 out_color;

#include "SpectrogramView.glsl"

layout(set = 2, binding = 0) readonly buffer Levels { float levels[]; };

// Match layouts.zig and spectrogram.comp.
const uint MAX_COLUMNS = 2048;
const float NO_TAPE = 1000.0;

// Matplotlib's inferno, as a polynomial fit (Matt Zucker's, CC0).
vec3 inferno(float t) {
    const vec3 c0 = vec3(0.0002189403691192265, 0.001651004631001012, -0.01948089843709184);
    const vec3 c1 = vec3(0.1065134194856116, 0.5639564367884091, 3.932712388889277);
    const vec3 c2 = vec3(11.60249308247187, -3.972853965665698, -15.9423941062914);
    const vec3 c3 = vec3(-41.70399613139459, 17.43639888205313, 44.35414519872813);
    const vec3 c4 = vec3(77.162935699427, -33.40235894210092, -81.80730925738993);
    const vec3 c5 = vec3(-71.31942824499214, 32.62606426397723, 73.20951985803202);
    const vec3 c6 = vec3(25.13112622477341, -12.24266895238567, -23.07032500287172);
    return clamp(c0 + t * (c1 + t * (c2 + t * (c3 + t * (c4 + t * (c5 + t * c6))))), 0.0, 1.0);
}

void main() {
    vec2 p = gl_FragCoord.xy;
    uint row = uint(u.size.y - p.y);
    uint x = uint(p.x);
    float db = levels[row * MAX_COLUMNS + (x + u.scroll) % uint(u.size.x)];
    if (x + u.filled < uint(u.size.x)) db = NO_TAPE;
    vec3 color = vec3(0.035, 0.03, 0.05);
    if (db < NO_TAPE) {
        float t = clamp((db - u.floor_db) / (u.ceil_db - u.floor_db), 0.0, 1.0);
        // A touch of contrast: quiet stays dark, loud blooms.
        color = inferno(pow(t, 1.3));
    }
    if (u.playhead >= 0.0) {
        float d = abs(p.x - u.playhead);
        color = mix(color, vec3(1.0, 0.85, 0.3), clamp(1.5 - d, 0.0, 1.0) * 0.8);
    }
    out_color = vec4(color, 1.0);
}